FORM TYPES

Создание новой формы

Modal form

Представляет собой самую простую форму, которая имеет лишь две кнопки и блок описания. Кнопки - это условный выбор ‘да’ или ‘нет’.
Созданная форма будет помещена в выражение last created form

create [a] [new] modal form (with (name|title)|named) %string%

Пример

create modal form named "Modal form":
  set form content to "Please select one option"
  run on form close:
    broadcast "closed"
  run on form open:
    broadcast "opened"
  form button named "I like skript!":
    broadcast "Thank you!!!"
  form button named "I didnt like skript!":
    broadcast "USE DENIZEN INSTEAD!!!"
open last created form to player

modal form

Simple form

Представляет собой форму c кнопками. Кнопок может быть неограниченное количество, помимо этого, кнопки могут иметь изображения из интернета.
Созданная форма будет помещена в выражение last created form

create [a] [new] simple form (with (name|title)|named) %string%

Пример

create simple form named "Simple form":
  form button named "button 1" with image "https://pics.clipartpng.com/Carrots_PNG_Clipart-465.png":
    broadcast "button 1 pressed"
  form button named "button 2":
    broadcast "button 2 pressed"
  form button named "button 3":
    broadcast "button 3 pressed"
open last created form to player

simple form

Custom form

Представляет собой форму c любыми элементами, кроме кнопок. Данный вид форм позволяет использовать слайдеры, переключатели, поля ввода, поля выбора и т.д
Обработка элементов формы осуществляется в секции on form result
Созданная форма будет помещена в выражение last created form

create [a] [new] custom form (with (name|title)|named) %string%

Пример

create custom form named "Custom form":
  form dropdown named "Select one value from list" with elements "one", "two", "three"
  form input named "Your password?" with placeholder "write your password"
  form label named "sample text"
  form slider named "music volume????" with minimum value 0 and maximum value 10
  form textslider named "select shit" with elements "value 1","value 2","value 3"
  form toggle named "yes or no?"
  run on form result:
    broadcast "%form toggle 1 value%"
open last created form to player

custom form

Последняя созданная форма

[the] (last[ly] [(created|edited)]|(created|edited)) form

Открыть форму игроку

open %form% (for|to) %players%

ЭЛЕМЕНТЫ ФОРМ

Кнопки

Кнопка представляет собой секцию, код внутри которой будет выполнен при клике на нее. После клика на кнопку - форма будет автоматически закрыта (особенность Bedrock форм).

form(-| )button ((with (name|title))|named) %string% [with image %string%]

create modal form named "Modal form":
  form button named "My button":
    broadcast "Pressed button"
open last created form to player

Текст Modal form.

Позволяет указать или получить текстовое описание в Modal form. Позволяет указать как в уже созданной форме, так и в секции создания Modal form

form['s] content

content of form 

%form%['s] content

content of %form%

create modal form named "Modal form":
  set content of form to "Sample text"
open last created form to player

Элементы Custom form

Получить значение элементов Custom form после закрытия можно только в секции run on form result.

Элемент пользовательского ввода

Создает элемент в который пользователь может ввести любой текст. Позволяет указать начальный текст внутри поля, и текст заполнитель

form(-| )input (with name|named) [%string% (with|and) [placeholder] %string%[(, | (with|and) ) [def[ault] [value]] %string%]]

Выбор из списка

Создает элемент в котором пользователь может выбрать одно из предложенных значений. Позволяет указать изначальное значение по индексу.

form(-| )drop[(-| )]down (with name|named) %string% (with|and) [elements] %strings%[(, | (with|and) ) [def[ault] [(element [index]|index)]] %number%]

Метка, заметка, текст

Создает элемент с текстом.

form(-| )label [(with (name|title)|named)] %string%

Ползунок с числовым выбором значения

Создает элемент в виде полоски со регулятором, в котором пользователь может указать значение. Позволяет указать минимальный и максимальный порог чисел, начальное значение и шаг ползунка.

form(-| )slider (with name|named) %string% [[(with|and) [min[imum] [value]] %number%[(, | (with|and) ) [max[imum] [value]] %number%[(, | (with|and) ) [def[ault] [value]] %number%[(, | (with|and) ) [[step] [value]] %number%]]]]

Ползунок с выбором значений

Создает аналогичный числовому ползунку элемент, но уже с текстовыми значениями. Позвлояет указать начальное значение по индексу.

form(-| )(text|step)[(-| )]slider (with name|named) %string% (with|and) [elements] %strings%[(, | (with|and) ) [def[ault] [(element [index]|index)]] %number%]

Элемент переключатель.

Имеет лишь два состояния , включено или выключено. Можно указать начальное состояние.

form(-| )toggle (with name|named) %string% [(with|and) [def[ault]] [value] %boolean%]

Обработка результатов

Получить игрока внутри формы

form(-| )player

Получение типа созданной формы

form[(-| )]type of %form%

%form%'s form[(-| )]type

Доступные типы форм для сравнения:

• custom form
• modal form
• simple form

Выполнить код при открытии/закрытии формы

run (when|while) (open[ing]|clos(e|ing)) [[the] form]

run (when|while) [the] form (opens|closes)

run on form (open[ing]|clos(e|ing))

create modal form named "Modal form":
  run on form close:
  	broadcast "%formplayer%" #will show name of player what close form
open last created form to player

Отменить или разрешить закрытие формы

По умолчанию закрытие формы разрешено. Если запретить, то форма будет переоткрыта после выбора

cancel [the] form clos(e|ing)

uncancel [the] form clos(e|ing)

Получить причину закрытия формы

[form(-| )]close reason

Доступные причины закрытия для сравнения:

• close
• (submit|success)
• invalid[ response]

Выполнить код при успешном закрытии формы

run on form (result|submit)

create custom form named "Custom form":
  form toggle named "toggle value"
  run on form result:
    broadcast "%form toggle 1 value%"
open last created form to player

Элементы Custom form

[form[(-| )]](drop[(-| )]down|input|slider|step[(-| )]slider|toggle) %number% [value]

value of [form[(-| )]](drop[(-| )]down|input|slider|step[(-| )]slider|toggle) %number%